home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD008b.dsk / EVASION.bas < prev    next >
BASIC Source File  |  2003-06-12  |  3KB  |  76 lines
  1. 0  IF  PEEK(104) < >12  OR  PEEK(3072)  THEN  TEXT : HOME : VTAB 12: PRINT "(PLEASE STAND BY...)": POKE 104,12: POKE 3072,0: PRINT  CHR$(4)"RUNEVASION"
  2. 5  ONERR  GOTO 630
  3. 10 X =  RND( - PEEK(78) - PEEK(79) *256): GOSUB 480
  4. 20  GOSUB 220
  5. 30 A =  PEEK(KB)
  6. 40 XM = (A = K) -(A = J)
  7. 50 YM = (A = M) -(A = I)
  8. 60 X1 = X1 +XM:Y1 = Y1 +YM:X1 = X1 +(X1 = 0) -(X1 = 39):Y1 = Y1 +(Y1 = 0) -(Y1 = 47)
  9. 70  IF  SCRN( X1,Y1) = C3  OR  SCRN( X1,Y1) = C4  THEN 200
  10. 80  COLOR= C5: PLOT X1,Y1
  11. 90  COLOR= C1: IF XO < >X1  OR YO < >Y1  THEN  PLOT XO,YO
  12. 100 XO = X1:YO = Y1: IF  RND(1) >.02  THEN 120
  13. 110 X1 =  INT(37 * RND(1)) +1:Y1 =  INT(45 * RND(1)) +1: CALL  -198: POKE CB,0: IF  SCRN( X1,Y1) < >C1  THEN 110
  14. 120  ON  INT(2 * RND(1)) +1 GOTO 130,140
  15. 130 X2 = X2 -(X1 <X2) +(X1 >X2): GOTO 150
  16. 140 Y2 = Y2 -(Y1 <Y2) +(Y1 >Y2)
  17. 150  COLOR= C3: PLOT X2,Y2: COLOR= C4: IF X2 < >AO  OR Y2 < >BO  THEN  PLOT AO,BO
  18. 160 AO = X2:BO = Y2
  19. 170  CALL FLIP
  20. 180 SC = SC +1
  21. 190  GOTO 30
  22. 200  FOR SO = 1 TO 50:BZ =  PEEK( -16336) + PEEK( -16336): NEXT 
  23. 210  GOTO 360
  24. 220 FLIP = 777
  25. 230 KB =  -16384:CB =  -16368
  26. 240 I = 201:J = 202:K = 203:M = 205
  27. 250 C1 = 12:C2 = 4:C3 = 2:C4 = 15:C5 = 0
  28. 260  RESTORE 
  29. 270  FOR LOC = 770 TO 812: READ NUM: POKE LOC,NUM: NEXT 
  30. 280  DATA 169,128,44,99,192,240,251,173,84,192,160,0,185,0,4,153,0,8,185,0,5,153,0,9,185,0,6,153,0,10,185,0,7,153,0,11,200,208,229,173,85,192,96
  31. 290  GR : POKE  -16302,0: CALL  -1998
  32. 300  COLOR= C1: FOR Y = 1 TO 23: HLIN 1,38 AT Y: HLIN 1,38 AT 47 -Y: NEXT 
  33. 310  COLOR= C2: HLIN 0,39 AT 0: HLIN 0,39 AT 47: VLIN 1,46 AT 0: VLIN 1,46 AT 39
  34. 320 X1 =  INT(37 * RND(1)) +2:Y1 =  INT(45 * RND(1)) +2
  35. 330 X2 =  INT(37 * RND(1)) +2:Y2 =  INT(45 * RND(1)) +2: IF X2 = X1  AND Y2 = Y1  THEN 330
  36. 340 XO = X1:YO = Y1:AO = X2:BO = Y2
  37. 350  RETURN 
  38. 360  TEXT : HOME : VTAB 7
  39. 370  PRINT "GAME STATISTICS:"
  40. 380  PRINT 
  41. 390  PRINT : PRINT 
  42. 400  PRINT "YOUR SCORE: "SC;: IF SC >HSC  THEN  FLASH : HTAB 23: PRINT "NEW HIGH SCORE!": NORMAL :HSC = SC
  43. 410  PRINT : IF HSC < >SC  THEN  PRINT 
  44. 420  PRINT "HIGH SCORE: "HSC
  45. 430  PRINT : PRINT 
  46. 440  POKE CB,0
  47. 450  PRINT "PRESS ";: INVERSE : PRINT "RETURN";: NORMAL : INPUT " TO PLAY AGAIN ";A$
  48. 460 SC = 0
  49. 470  GOTO 20
  50. 480  TEXT : HOME : VTAB 3
  51. 490  HTAB 11: PRINT "EVASION... BY JIM GANZ"
  52. 500  PRINT : PRINT 
  53. 510  PRINT "   THE OBJECT OF THIS LOW-RES GAME IS TO
  54. 520  PRINT "EVADE A GROWING WORM FOR AS LONG AS YOU "
  55. 530  PRINT "CAN. USE THE I,J,K,M KEYS TO MOVE, AND  "
  56. 540  PRINT "ANY OTHER KEY TO STOP WHERE YOU ARE.    "
  57. 550  PRINT "AT TIMES, YOU MAY MAKE A RANDOM 'LEAP': "
  58. 560  PRINT "THIS CAN BE GOOD OR BAD..."
  59. 570  PRINT 
  60. 580  PRINT "   YOUR SCORE IS BASED ON HOW LONG YOU  "
  61. 590  PRINT "LAST - GOOD LUCK!"
  62. 600  VTAB 23
  63. 610  HTAB 10: PRINT "PRESS ";: INVERSE : PRINT "RETURN";: NORMAL : INPUT " TO BEGIN ";A$
  64. 620  RETURN 
  65. 630  POKE  -16300,0: TEXT : HOME : TEXT : NORMAL : POKE CB,0: END 
  66. 65535  REM *********************
  67. 65535  REM *     "EVASION"     *
  68. 65535  REM *   BY   JIM GANZ   *
  69. 65535  REM *   82 SPRING LANE  *
  70. 65535  REM *   WEST HARTFORD,  *
  71. 65535  REM *   CONN.    06107  *
  72. 65535  REM *                   *
  73. 65535  REM *   PAGE-SWITCHING  *
  74. 65535  REM * ROUTINE BY CHARLIE*
  75. 65535  REM *      KELLNER.     *
  76. 65535  REM *********************